diff options
| author | yuan linyu <Linyu.Yuan@alcatel-sbell.com.cn> | 2017-06-18 16:48:17 +0200 |
|---|---|---|
| committer | David S. Miller <davem@davemloft.net> | 2017-06-20 19:30:14 +0200 |
| commit | de77b966ce8adcb4c58d50e2f087320d5479812a (patch) | |
| tree | b18e9a0dc3694a7d7165ec8631801d6ba47de15f /block/ioprio.c | |
| parent | net: dsa: mv88e6xxx: better IEEE Prio Mapping Table description (diff) | |
| download | linux-de77b966ce8adcb4c58d50e2f087320d5479812a.tar.xz linux-de77b966ce8adcb4c58d50e2f087320d5479812a.zip | |
net: introduce __skb_put_[zero, data, u8]
follow Johannes Berg, semantic patch file as below,
@@
identifier p, p2;
expression len;
expression skb;
type t, t2;
@@
(
-p = __skb_put(skb, len);
+p = __skb_put_zero(skb, len);
|
-p = (t)__skb_put(skb, len);
+p = __skb_put_zero(skb, len);
)
... when != p
(
p2 = (t2)p;
-memset(p2, 0, len);
|
-memset(p, 0, len);
)
@@
identifier p;
expression len;
expression skb;
type t;
@@
(
-t p = __skb_put(skb, len);
+t p = __skb_put_zero(skb, len);
)
... when != p
(
-memset(p, 0, len);
)
@@
type t, t2;
identifier p, p2;
expression skb;
@@
t *p;
...
(
-p = __skb_put(skb, sizeof(t));
+p = __skb_put_zero(skb, sizeof(t));
|
-p = (t *)__skb_put(skb, sizeof(t));
+p = __skb_put_zero(skb, sizeof(t));
)
... when != p
(
p2 = (t2)p;
-memset(p2, 0, sizeof(*p));
|
-memset(p, 0, sizeof(*p));
)
@@
expression skb, len;
@@
-memset(__skb_put(skb, len), 0, len);
+__skb_put_zero(skb, len);
@@
expression skb, len, data;
@@
-memcpy(__skb_put(skb, len), data, len);
+__skb_put_data(skb, data, len);
@@
expression SKB, C, S;
typedef u8;
identifier fn = {__skb_put};
fresh identifier fn2 = fn ## "_u8";
@@
- *(u8 *)fn(SKB, S) = C;
+ fn2(SKB, C);
Signed-off-by: yuan linyu <Linyu.Yuan@alcatel-sbell.com.cn>
Signed-off-by: David S. Miller <davem@davemloft.net>
Diffstat (limited to 'block/ioprio.c')
0 files changed, 0 insertions, 0 deletions